File:Hall effect.png

預覽大小：598 × 599 像素。其他解析度：240 × 240 像素 | 479 × 480 像素 | 984 × 986 像素。

原始檔案（984 × 986 像素，檔案大小：401 KB，MIME 類型：image/png）

本檔案並非來自中文維基百科，而是來自維基共享資源。請參閱維基共享資源上的詳細描述、討論頁、頁面歷史、日誌。

維基共享資源是一個儲存自由版權作品的項目。您可以向此項目作出貢獻。


	該圖片為維基共享資源的特色圖片(Featured pictures)。它被認定為最佳圖像之一。該圖片為德文維基百科的特色圖片(Exzellente Bilder)。它被認定為最佳圖像之一。該圖片為土耳其文維基百科的特色圖片(Seçkin resimler)。它被認定為最佳圖像之一。如果您還有可以在合適授權條款下發表的相似品質的圖像，歡迎您上傳、標註授權條款並提名之。

描述

English: Shows the Hall effect for different directions of electric current and magnetic field.

Legend:

Electrons (not conventional current!)
Hall element, or Hall sensor
Magnets
Magnetic field
Power source

In drawing "A", the Hall element takes on a negative charge at the top edge (symbolised by the blue color) and positive at the lower edge (red color). In "B" and "C", either the electric current or the magnetic field is reversed, causing the polarization to reverse. Reversing both current and magnetic field (drawing "D") causes the Hall element to again assume a negative charge at the upper edge.

Rendered using POV-Ray. The scene description "code" shown below supports rendering all of the four "situations" portrayed in the image - see the comment given in the code in the page discussion. The four images were subsequently combined, and the numbers and letters added, in a graphics software package.

Deutsch: Diese Grafik illustriert den Halleffekt unter verschiedenen Richtungen des Elektronenflusses/des Magnetfeldes.

Legende:

Elektronen
Hallsensor/-element
Magneten
magnetisches Feld
Spannungsquelle

In Abbildung A wird im oberen Bereich ein Elektronenüberschuss (durch die blaue Farbe symbolisiert), im unteren Bereich ein Elektronenmangel (rote Farbe) erzeugt. In den Abbildungen B und C ist der Elektronenfluss bzw. der Magnet in eine andere Richtung gebracht worden, weshalb die Polarisierung des Hallelementes umgekehrt ist.

Wird sowohl der Elektronenfluss als auch das magnetische Feld umgekehrt (Abbildung D), entsteht wie in Abbildung A ein Elektronenmangel im unteren Bereich.

Français : Effet Hall pour différents sens du courant et du champ magnétique.

Légende:

Électrons (et non le Sens conventionnel !)
Élément ou Capteur à effet Hall
Aimants
Champ magnétique
Source de courant

Dans le dessin A, une charge négative apparait à la bordure haute de l'élément (couleur bleue), et une charge positive à sa bordure basse (couleur rouge). En B et C, l'inversion du sens du courant ou de celui du champs magnétique provoque l'inversion de cette polarisation. En D, la double inversion du courant électrique et du champs magnétique donnent à l'élément la même polarisation qu'en A.

Dessins réalisés en utilisant le logiciel POV-Ray. Le code et des remarques complémentaires sont disponibles dans la discussion.

For more translations SEE BELOW

日期

2005年4月10日

來源

自己的作品

作者

Peo

授權許可
(重用此檔案)

我，本作品的著作權持有者，決定用以下授權條款發佈本作品：

已授權您依據自由軟體基金會發行的無固定段落、封面文字和封底文字GNU自由文件授權條款1.2版或任意後續版本，對本檔進行複製、傳播和／或修改。該協議的副本列在GNU自由文件授權條款中。

	此檔案採用共享創意姓名標示-相同方式分享 3.0 未在地化版本授權條款。

	您可以自由：分享 – 複製、發佈和傳播本作品重新修改 – 創作演繹作品惟需遵照下列條件：姓名標示 – 您必須指名出正確的製作者，和提供授權條款的連結，以及表示是否有對內容上做出變更。您可以用任何合理的方式來行動，但不得以任何方式表明授權條款是對您許可或是由您所使用。相同方式分享 – 如果您利用本素材進行再混合、轉換或創作，您必須基於如同原先的相同或兼容的條款，來分布您的貢獻成品。
	已新增授權條款標題至此檔案，作為GFDL授權更新的一部份。CC BY-SA 3.0truetrue

您可以選擇您需要的授權條款。

其他版本

only shows case A

Awards

This image was selected as picture of the day on Wikimedia Commons for 19 October 2005. It was captioned as follows:

English: Hall effect

Other languages:

Aragonés: Efeuto Hall

Čeština: Hallův jev

Deutsch: Illustration des Hall-Effekts

Eesti: Hall'i effekti illustratsioon

English: Hall effect

Español: Ilustración del efecto Hall

Français : L'effet Hall illustré

Gaeilge: Iarmhairt Hall

Galego: Efeto Hall.

Latina: Hall effectus.

Nederlands: Illustratie nl:Hall-effect

Polski: Efekt Halla

Português: Diagrama do efeito Hall

Slovenščina: Hallov pojav

Suomi: Hallin efekti

Русский: Эффект Холла

ไทย: ปรากฏการณ์ฮอลล์

日本語：ホール効果

中文：哈尔效应示意图

Čeština: Tento obrázek byl vybrán jako obrázek týdne na České Wikipedii pro 1. týden roku 2007.

Dansk: Dette billede har været valgt som ugens billede på den Tjekkiske Wikipedia i uge 1, 2007.

Deutsch: Dieses Bild wurde als Bild der Woche auf der tschechischen Wikipedia für die 1. Woche 2007 ausgewählt.

English: This image was selected as a picture of the week on the Czech Wikipedia for 1^st week, 2007.

Français : Cette image est sélectionnée en tant qu’image de la semaine sur la Wikipédia Tchèque pour la 1^e semaine de 2007.

Italiano: Questa immagine è stata selezionata come Immagine della settimana su Wikipedia in ceco per la I settimana del 2007.

Magyar: Ezt a képet 2007 1. hetében a hét képének választották a cseh Wikipédián.

Svenska: Denna bild valdes som veckans bild på tjeckiskspråkiga Wikipedia för vecka 1, 2007.

Македонски: Сликава е избрана за слика на неделата на чешката Википедија за I недела од 2007 година.

Русский: Эта иллюстрация была выбрана изображением недели в чешском разделе «Википедии» для недели номер 1 2007 года.

Українська: Ця ілюстрація була вибрана зображенням тижня в чеському розділі «Вікіпедії» для тижня номер 1, 2007 року.

العربية : اُختيرت هذه الصُّورة لتكون صُورة الأسبوع في ويكيبيديا التشيكية في الأسبوع 1 في سنة 2007.

Rendered using POV-Ray (see http://www.povray.org). The scene description "code" shown below supports rendering all of the four "situations" portrayed in the image - see the comment given in the code. The four images were subsequently combined, and the numbers and letters added, in a graphics software package. POV-Ray "code" for rendering all four parts of the illustration:

 /*
 ====================================================
 The Hall effect in metal under various circumstances
 ----------------------------------------------------
 Created by Søren Peo Pedersen - see my user page at
 http://da.wikipedia.org/wiki/Bruger:Peo
 ====================================================
 */
 
 #declare NorthAtLeft=no; // Orientation of magnetic field:
 // Use "yes" for north pole to the left, and south pole to the right
 // Use "no" for north pole to the right, and south pole to the left
 
 #declare PlusTowardsViewer=yes;  // Direction of current:
 // Use "yes" to have the positive pole at the ends of battery and Hall sensor nearest to viewer
 // Use "no" to have the negative pole at the ends of battery and Hall sensor nearest to viewer
 
 #declare PositiveCharge=no; // Polarity (color) of charge carriers in the circuit:
 // Use "yes" for orangeish colored charge carriers in wires and Hall sensor
 // Use "no" for light blue colored charge carriers in wires and Hall sensor
 
 #declare HallUpwards=yes; // Direction of sideways force upon charge carriers:
 // Use "yes" to have the charge carriers "bend upwards" inside Hall element
 // Use "no" to have the charge carriers "bend downwards" inside Hall element
 
 #declare NegativeEdgeUp=yes;  // Electrical polarization of Hall element (indicated by color):
 // Use "yes" to have bluish color at top of Hall element, indicating negative charge here
 // Use "no" to have reddish color at top of Hall element, indicating positive charge here
 
 #declare MagnetFont="arialbd.ttf" // Font for the "N" and "S" nomenclature on magnets
 
 // -----------------------------------------------------------------------------------------
 
 #declare txtNeutralElement=texture {  // Texture for electrically neutral parts of Hall element
   pigment {color rgbft <.5,.5,.5,1,0>}
   finish {
     reflection rgb .5
     phong 1
     metallic
     }
   }
   
 #declare txtNegativeElement=texture { // Texture for negatively charged parts of Hall element
   pigment {color rgbft <.1,.3,.9,1,0>}
   finish {
     reflection rgb <.1,.3,.9>
     phong 1
     metallic
     }
   }
   
 #declare txtPositiveElement=texture { // Texture for positively charged parts of Hall element
   pigment {color rgbft <.9,.3,.1,1,0>}
   finish {
     reflection rgb <.9,.3,.1>
     phong 1
     metallic
     }
   }
 
 #declare txtPolarisedElement=texture {  // Texture for polarized parts of the Hall element
   gradient y
   texture_map {
     [0 txtNegativeElement]
     [.5 txtNeutralElement]
     [1 txtPositiveElement]
     }
   translate <0,-.5,0>
   #if (NegativeEdgeUp)
     rotate <180,0,0>
   #end
   }
 
 #declare txtHallElement=texture { // Complete texture for the entire Hall element
   gradient z
   texture_map {
     [0 txtNeutralElement]
     [.5 txtPolarisedElement]
     [1 txtNeutralElement]
     }
   translate <0,0,-.5>
   scale 4
   }
 
 #declare WireTxt=texture {  // Texture for the wires connecting Hall element with power source
   pigment {color rgb .5}
   finish {
     reflection rgb .7
     phong 3
     metallic
     }
   }
 
 #declare Qtorus=intersection{   // 1/4 of a torus, for rounded "corner" on the wiring
   torus {1,.06 rotate <0,0,90>}
   box {-2,<2,0,0>}    
   }
 
 #declare PlusPgmt=pigment {   // Pigment for positive end of the battery (power source)
   object {
     merge {
       box {<-.3,0, .35>,<.3,1,.45>}
       box {<-.05,0, .1>,<.05,1,.7>}
       }
     pigment {color rgb <1,0,0>}
     pigment {color rgb 1}
     }
   }
 
 #declare MinusPgmt=pigment {  // Pigment for negative end of the battery (power source)
   object {        
     box {<-.3,0,-.55>,<.3,1,-.45>}
     pigment {color rgb <0,0,1>}
     pigment {color rgb 1}
     }
   }
 
 #declare PowerSource=union {  // Power source, symbolised by a battery
   merge {
     torus {.45,.05 rotate <90,0,0> translate <0,0,-.95>}
     cylinder {<0,0,-.95>,<0,0,.8>,.5}
     torus {.45,.05 rotate <90,0,0> translate <0,0, .8>}
     pigment {
       object {
         plane {<0,0,1>,0}
         pigment {PlusPgmt}
         pigment {MinusPgmt}
         }
       rotate <0,0,-35>
       }
     finish {ambient .4}
     }
   merge {
     torus {.35,.05 rotate <90,0,0> translate <0,0,-.95>}
     cylinder {<0,0,-1>,<0,0,-.9>,.35}
     torus {.35,.05 rotate <90,0,0> translate <0,0,.8>}
     cylinder {<0,0,.85>,<0,0,.8>,.35}
     difference {
       cylinder {<0,0,.85>,<0,0,.9>,.15}
       torus {.15,.05 rotate <90,0,0> translate <0,0,.9>}
       }
     cylinder {<0,0,.9>,<0,0,.95>,.1}
     torus {.05,.05 rotate <90,0,0> translate <0,0,.95>}
     cylinder {<0,0,.95>,<0,0,1>,.05}
     pigment {color rgb .5}
     finish {reflection rgb .9 phong 1 metallic}
     }
   }
 
 #macro txtChargeCarrier(Transparency) // Texture for charge carriers and their "motion blur tails"
 pigment {color rgbt <
   #if (PositiveCharge)
   1,.5,.2,Transparency
   #else
   .2,.5,1,Transparency
   #end
   >}
 finish {ambient .4}
 #end
 
 #declare FieldArrow=merge {   // Arrow indicating direction of magnetic field
   cylinder {<-2.5,0,0>,<2.3,0,0>,.003}
   cone {<2.3,0,0>,.05,<2.5,0,0>,0}
   pigment {color rgb 0}
   #if (NorthAtLeft)
   #else
   scale <-1,1,1>
   #end
   no_shadow
   no_reflection    
   }
 
 #declare StraightCharge=union {   // Charge carrier with straight "motion blur tail"
   sphere {0,.15 texture {txtChargeCarrier(0)}}
   cylinder {0,<0,0,.499>,.15 hollow
     texture {
       gradient z
       texture_map {
         [0 txtChargeCarrier(0)]
         [1 txtChargeCarrier(1)]
         }
       scale .5
       }        
     }
   no_shadow
   no_reflection
   }
 
 #declare CurvedCharge=union {   // Charge carrier with curved "motion blur tail"
   sphere {<0,-1,0>,.15 texture {txtChargeCarrier(0)}}
   difference {
     torus {1,.15 rotate <0,0,90>}
     plane {<0,0,1>,0}
     plane {<0,0,-1>,0 rotate <-29.99,0,0>}
     hollow
     texture {
       radial
       texture_map {
         [0 txtChargeCarrier(.3)]
         [1 txtChargeCarrier(1)]
         }
       frequency 12
       rotate <0,0,90>
       }
     }
   no_shadow
   no_reflection
   }
 
   // The scenario:  
   box {<-.16,-1,-2>,<.16,1,2>   // The hall element
     texture {txtHallElement}        
     no_shadow
     }
   
   merge { // Wiring with travelling charge carriers
     // Wiring on the side towards the viewer:
     cylinder {<0,0,-2>,<0,0,-3>,.06}
     #object {Qtorus rotate <90,0,0> translate <0,-1,-3>}
     cylinder {<0,-1,-4>,<0,-2,-4>,.06}
     #object {Qtorus translate <0,-2,-3>}
     cylinder {<0,-3,-3>,<0,-3,-1>,.06}
     // Wiring on the side facing away from the viewer:
     cylinder {<0,-3, 1>,<0,-3, 3>,.06}
     #object {Qtorus rotate <-90,0,0> translate <0,-2,3>}
     cylinder {<0,-1, 4>,<0,-2, 4>,.06}
     #object {Qtorus rotate <180,0,0> translate <0,-1,3>}
     cylinder {<0,0, 2>,<0,0, 3>,.06}
     texture {WireTxt}
     }
 
   union { // Charge carriers:
     // Charge carriers on the side towards the viewer:
     #object {StraightCharge translate <0,-3,-2.7>}
     #object {CurvedCharge rotate <30,0,0> translate <0,-2,-3>}
     #object {CurvedCharge rotate <90,0,0> translate <0,-2,-3>}
     #object {StraightCharge rotate <90,0,0> translate <0,-1,-4>}
     #object {StraightCharge rotate <90,0,0> translate <0,-1,-4>}
     #object {CurvedCharge rotate <150,0,0> translate <0,-1,-3>}
     #object {StraightCharge rotate <180,0,0> translate <0,0,-2.5>}
     // Charge carriers inside Hall element:
     #if (HallUpwards)
       #object {CurvedCharge rotate <195,0,0> translate <0,-.3,0>}
       #object {CurvedCharge rotate <30,180,0> translate <0,1.15,-1.5>}
       #object {CurvedCharge rotate <0,180,0> translate <0,1.15,1.5>}
     #else
       #object {CurvedCharge rotate <210,0,0> translate <0,-1,-1.5>}
       #object {CurvedCharge rotate <15,180,0> translate <0,.3,0>}
       #object {CurvedCharge rotate <180,0,0> translate <0,-1,1.5>}
     #end
     // Charge carriers on the side facing away from the viewer:
     #object {StraightCharge rotate <180,0,0> translate <0,0,3>}
     #object {CurvedCharge rotate <270,0,0> translate <0,-1,3>}
     #object {StraightCharge rotate <270,0,0> translate <0,-2,4>}
     #object {CurvedCharge rotate <330,0,0> translate <0,-2,3>}
     #object {StraightCharge translate <0,-3,2.3>}
     #if (PlusTowardsViewer)
       scale <1,1,-1>
     #end
     }
       
   #object {PowerSource  // The battery symbolising the power source of the circuit
       #if (PlusTowardsViewer) scale <1,1,-1> #end
       scale 2
       translate <0,-3,0>
       }
   
   #union {    // Pair of magnets
     // The magnet at the left-hand side of the image:
     box {<-15,-1,-1>,<-3,1,1>
       pigment {
         object {
           text {ttf MagnetFont
             #if (NorthAtLeft) "N" #else "S" #end
             ,3,0
             scale 2
             translate <-4.3,-.7,-1.5>
             }
           #if (NorthAtLeft)
             color rgb <1,0,0>
             color rgb .85
           #else
             color rgb .85
             color rgb <1,0,0>
           #end
           }
         }
       finish {ambient .4}
       no_shadow
       no_reflection
       }
     // The magnet at the right-hand side of the image:
     box {<3,-1,-1>,<15,1,1>
       pigment {
         object {
           text {ttf MagnetFont
             #if (NorthAtLeft) "S" #else "N" #end
             ,3,0
             scale 2
             translate <3.2,-.7,-1.5>
             }
           #if (NorthAtLeft)
             color rgb .85
             color rgb <1,0,0>
           #else
             color rgb <1,0,0>
             color rgb .85
           #end
           }
         }
       finish {ambient .4}
       no_shadow
       no_reflection
       }
     }
 
 // 4 x 4 arrows to indicate the direction of the magnetic field:
 #local Ktal=-.75;
 #while (Ktal<1)
   #local Rtal=-.75;
   #while (Rtal<1)
     #object {FieldArrow translate <0,Rtal,Ktal>}
     #local Rtal=Rtal+.5;
   #end
   #local Ktal=Ktal+.5;
 #end
 
 // Point of view:
 camera {
     location <4,3,-5>
     look_at <.8,-1.3,0>
     }
 
 // Illumination:
 light_source {<20,10,-15> color rgb 1}
 light_source {<-10,20,10> color rgb 1}
 
 // Spotty surroundings outside viewfield to enhance reflective surfaces:
 #declare Spotty=pigment {
   marble
   color_map {
     [0 color rgb 0]
     [1 color rgb .8]
     }
   scale .1
   }
 
 sky_sphere {
   pigment {
     gradient z
     pigment_map {
       [0.00 Spotty]
       [0.88 Spotty]
       [0.88 color rgb 1]
       [1.00 color rgb 1]
       }
     translate -.5
     scale 2
     rotate <35,-32,0>
     }
   }

檔案歷史

點選日期/時間以檢視該時間的檔案版本。

	日期/時間	縮⁠圖	尺寸	用戶	備⁠註
目前	2005年4月10日 (日) 03:00		984 × 986（401 KB）	Peo~commonswiki	Shows the Hall effect for different directions of electric current and magnetic field.

檔案用途

下列6個頁面有用到此檔案：

全域檔案使用狀況

以下其他 wiki 使用了這個檔案：

ar.wikipedia.org 的使用狀況
- تأثير هول
- بوابة:إلكترونيات/صورة
- بوابة:إلكترونيات/صورة/3
- مستخدم:صندوق مستخدم/يكره الفيزياء
- مستخدم:Heila Al-Mogren/صناديقي
- مستخدم:Heila Al-Mogren
- مستخدم:صندوق مستخدم/مستخدم يكره الفيزياء
ast.wikipedia.org 的使用狀況
- Corriente llétrico
az.wikipedia.org 的使用狀況
- Daşıyıcı tezlik
be.wikipedia.org 的使用狀況
- Эфект Хола
bg.wikipedia.org 的使用狀況
- Датчик на Хол
- Ефект на Хол
ca.wikipedia.org 的使用狀況
- Efecte Hall
cs.wikipedia.org 的使用狀況
- Hallův jev
- Wikipedie:Obrázek týdne/2007
- Wikipedie:Obrázek týdne/2007/01
da.wikipedia.org 的使用狀況
- Brugerdiskussion:Peo
- Hall-effekt
- Wikipedia:Dagens artikel/september 2004
- Wikipedia:Dagens artikel/18. september 2004
de.wikipedia.org 的使用狀況
- Hall-Effekt
- Datei:Hall effect.png
- Wikipedia:Kandidaten für exzellente Bilder/Archiv2005/8
- Benutzer:Cmoder/Grafiktipps
- Wikipedia:Exzellente Bilder/Naturwissenschaften
- Wikipedia:Grafiktipps/Programme
- Wikipedia:Exzellente Bilder/Kleine Bilder
el.wikipedia.org 的使用狀況
- Αισθητήρας Χολ
en.wikipedia.org 的使用狀況
- Hall effect
- Wikipedia:Reference desk/Archives/Science/2006 July 30
- Portal:Electronics/Selected picture
- Portal:Electronics/Selected picture/13
en.wikiversity.org 的使用狀況
- Materials Science and Engineering/List of Topics
es.wikipedia.org 的使用狀況
- Corriente eléctrica
- Efecto Hall
fa.wikipedia.org 的使用狀況
- اثر هال
fi.wikipedia.org 的使用狀況
- Hallin ilmiö
fr.wikipedia.org 的使用狀況
- Effet Hall
- Wikipédia:Image du jour/19 octobre 2005
- Wikipédia:Image du jour/octobre 2005
- Discussion:Champ magnétique
fr.wikisource.org 的使用狀況
- Utilisateur:Zyephyrus/Icônes
fr.wikiversity.org 的使用狀況
- Discussion:Introduction à l'infographie
he.wikipedia.org 的使用狀況
- ויקיפדיה:תמונה מומלצת/הוספה למומלצים/ארכיון 15
hr.wikipedia.org 的使用狀況
- Horst Ludwig Störmer
- Hallov učinak
- Klaus von Klitzing
- Kvantni Hallov učinak
hu.wikipedia.org 的使用狀況
- Hall-effektus
hy.wikipedia.org 的使用狀況
- Հոլի էֆեկտ

檢視此檔案的更多全域使用狀況。

詮釋資料

此檔案中包含擴展的資訊。這些資訊可能是由數位相機或掃描器在建立時或數位化過程中所加入。

如果此檔案的來源檔案已被修改，一些資訊在修改後的檔案中將不能完全反映出來。

檔案修改日期時間	2005年4月10日 (日) 02:59

File:Hall effect.png

Awards

說明

在此檔案描寫的項目

描繪內容

創作作者

沒有維基數據項目的某些值

著作權狀態 ^{繁體中文 (已轉換拼寫)}

有著作權 ^{繁體中文 (已轉換拼寫)}

特許條款

GNU自由文檔許可證1.2或更高版本 ^{繁體中文 (已轉換拼寫)}

共享創意署名-相同方式共享3.0Unported

共享資源質素評價 ^{繁體中文 (已轉換拼寫)}

維基共享資源特色圖片 ^{中文 (已轉換拼寫)}

檔案來源 ^{Chinese (Taiwan) (已轉換拼寫)}

上傳者的原創作品 ^{繁體中文 (已轉換拼寫)}

成立或建立時間

10 4 2005

多媒體型式 ^{繁體中文 (已轉換拼寫)}

image/png

檔案歷史

檔案用途

全域檔案使用狀況

詮釋資料

Awards

說明

在此檔案描寫的項目

描繪內容

創作作者

沒有維基數據項目的某些值

著作權狀態 繁體中文 (已轉換拼寫)

有著作權 繁體中文 (已轉換拼寫)

特許條款

GNU自由文檔許可證1.2或更高版本 繁體中文 (已轉換拼寫)

共享創意署名-相同方式共享3.0Unported

共享資源質素評價 繁體中文 (已轉換拼寫)

維基共享資源特色圖片 中文 (已轉換拼寫)

檔案來源 Chinese (Taiwan) (已轉換拼寫)

上傳者的原創作品 繁體中文 (已轉換拼寫)

成立或建立時間

10 4 2005

多媒體型式 繁體中文 (已轉換拼寫)

image/png

檔案歷史

檔案用途

全域檔案使用狀況

詮釋資料

著作權狀態 ^{繁體中文 (已轉換拼寫)}

有著作權 ^{繁體中文 (已轉換拼寫)}

GNU自由文檔許可證1.2或更高版本 ^{繁體中文 (已轉換拼寫)}

共享資源質素評價 ^{繁體中文 (已轉換拼寫)}

維基共享資源特色圖片 ^{中文 (已轉換拼寫)}

檔案來源 ^{Chinese (Taiwan) (已轉換拼寫)}

上傳者的原創作品 ^{繁體中文 (已轉換拼寫)}

多媒體型式 ^{繁體中文 (已轉換拼寫)}